Discrete Fourier series

n=200;

(*list*)
a=Table[RandomReal[],{i,1,n-1}];

(*modes*)
Grid[Partition[Table[ListPlot[Table[{i,Sin[j Pi i/n]},{i,0,n}],Joined->True,Frame->True],{j,1,n-1}],3]]

(*Fourier transform*)
α=Table[Sum[Sin[j Pi i/n]a[[i]],{i,1,n-1}]*2/n,{j,1,n-1}];

(*list again*)
aa=Table[Sum[Sin[j Pi i/n]α[[j]],{j,1,n-1}],{i,1,n-1}];

(*comparison*)
gr1=ListPlot[a,Frame->True];
gr2=ListPlot[aa,Frame->True,PlotStyle->{Red,PointSize[Large]}];

Show[gr2,gr1]

Modelling assignment

Properties [kg,m,s]

val={
(*COLUMN DATA*)
Es->210*10^9,(*Young's modulus of steel*)
νs->0.3,
Gs->Es/(2+2*νs),
ρs->7800, (*column density*)
dmaj->0.006, (*nominal diamater*)
P->0.001, (*pitch*)
d->dmaj-2/Sqrt[3] P, (*effective diameter*)
h->0.156, (*floor-to-floor distance*)
lx->0.410, (*column spacing*)
ly->0.243, (*column spacing*)

(*FLOOR DATA*)
Ea->70*10^9,(*Young's modulus of aluminum*)
νa->0.3,
Ga->Ea/(2+2*νa),
ρa->2700, (*floor density*)
L->0.440, (*floor length*)
W->0.295, (*floor width*)
t->0.015, (*floor thickness*)

(*PLASTIC STRIP DATA*)
Ep->3*10^9,
νp->0.3,
Gp->Ep/(2+2*νp),
ρp->1000,
w->0.05, (*strip width*)
s->0.002 (*strip thickness*)
};

Grid[Partition[Flatten[(val /.Rule->List) /. {a_,b_}->{a,b}],4],Alignment->Left,Spacings->{5,1.2},Frame->All]

Acceleration signal analysis

(*acceleration time series*)
SetDirectory[NotebookDirectory[]];
series=Import["experiment_5.xlsx"][[1]];
g1=ListPlot[series,Joined->True,PlotRange->{{0.67,1.67},All},Frame->True,FrameLabel->{"t [s]","a [m/(s^2)"}]

(*frequence domain representation*)
data=Transpose[series];
T=Last[data[[1]]]-First[data[[1]]];
absλ=Abs[Fourier[data[[2]]]];  

(*amplitude as function of frequency*)
fλ=MapIndexed[{(First[#2]-1)/T,#1}&,absλ];
g2=ListPlot[fλ,Joined->True,PlotRange->{{0,100},All},Frame->True,FrameLabel->{"f [1/s]","α [m/(s^2)]"}]

(*find the peaks and pick the two first*)
peakp=FindPeaks[absλ][[1;;2,1]];
fλ[[peakp,1]]

Simplified models

(*Parameters of models*) 
par={mf->ρa L W t,mb->4 ρs (((d^2) π)/4) h,kb->4*12((Es (d^4) π)/(64 (h^3))) } //.val;

Grid[Partition[Flatten[(par/.Rule->List) /. {a_,b_}->{a,b}],2],Alignment->Left,Spacings->{5,1.2},Frame->All]

(*Mass and stiffness matrices by PSM*) 

M=mf(({{1, 0}, {0, 1}}))+(mb/2)(({{2, 0}, {0, 1}}));   K=kb(({{2, -1}, {-1, 1}}));

{vals,vecs}=Eigensystem[Inverse[M].K] /.par;
Sqrt[vals]/(2 Pi)
vecs[[1]]/Norm[vecs[[1]]]
vecs[[2]]/Norm[vecs[[2]]]

(*Mass and stiffness matrices by FDM*) 

M=mf(({{1, 0}, {0, 1}}))+mb(({{1, 0}, {0, 1}}));   K=kb(({{2, -1}, {-1, 1}}));

{vals,vecs}=Eigensystem[Inverse[M].K] /.par
Sqrt[vals]/(2 Pi)
vecs[[1]]/Norm[vecs[[1]]] //N
vecs[[2]]/Norm[vecs[[2]]] //N

(*Mass and stiffness matrices by FEM*) 

M=mf(({{1, 0}, {0, 1}}))+(mb/6)(({{4, 1}, {1, 2}}));   K=kb(({{2, -1}, {-1, 1}}));

{vals,vecs}=Eigensystem[Inverse[M].K] /.par;
Sqrt[vals]/(2 Pi)
vecs[[1]]/Norm[vecs[[1]]] //N
vecs[[2]]/Norm[vecs[[2]]] //N