MS-A0201 Diff. int. 2 (TFM)

Luento 6: Ääriarvojen luokittelu

Harri Hakula  /Kevät 2022

Hessen matriisi

Tarkastellaan funktiota f(x,y) = ((x^2)-y)/((x^2)+(y^2)+1), sen ääriarvoja origon läheisyydessä ja luokitellaan ne.

f[x_,y_]:=(x^2-y)/(x^2+y^2+1);
GraphicsGrid[List@List[
Plot3D[f[x,y],{x,-2,2},{y,-2,2}],ContourPlot[f[x,y],{x,-2,2},{y,-2,2}]
],ImageSize->Full]

Gradientti ja Hessen matriisi

Muodostetaan funktion f(x,y) = ((x^2)-y)/((x^2)+(y^2)+1) gradientti ja Hessen matriisi.

gradient[x_,y_]=Function[{f},D[f,{{x,y}}]];
hessian[x_,y_]=Function[{f},D[f,{{x,y}},{{x,y}}]];
grad=gradient[x,y][f[x,y]]//FullSimplify;
hess=hessian[x,y][f[x,y]]//FullSimplify;
MatrixForm[grad]
MatrixForm[hess]

Ääriarvojen luokittelu

Etsitään gradientin nollakohdat ja nollakohdassa evaluoidun Hessen matriisin ominiasarvot.

crit=Solve[Thread[grad==0],{x,y}]

Eigenvalues[hess/.#]&/@crit

PositiveDefiniteMatrixQ[hess/.#]&/@crit

NegativeDefiniteMatrixQ[hess/.#]&/@crit

IndefiniteMatrixQ[hess/.#]&/@crit